*=============SEPIC_Duty_Cycle_Plots==================


Sometimes being able to put more information on a single

plot is useful. Being able to sweep something can make it

harder for a problem to hide. 


=======================================================================


SEPIC_Converter

*            _  _  _

*    ___    / \/ \/ \ V1   V1D  D1  ___      RL1

*   |VIN|___| () () |___||____|\|__|OUT|___/\  /\  /\__

*   |___|  |   L1     | || |  |/|  |___| |   \/  \/   _|_

*         _|_         | C1 |  _  _  _    |    COUT    ///

*    CIN  ___   S1 /  |    | / \/ \/ \   |__||__

*          |______/  _|    |_| () () |_     || _|_

*             _|_               L1B   _|_      ///

*             ///                     ///


  SEPICloaded.jpg

plot      out5k out50 out10 vs vd


=======================================================================


Sometimes being able to sweep in more than one direction

is useful. The plot above shows a SEPIC Converter

which has undergone a 0% to 100% sweep in duty cycle over

a 1msec transient analysis for three different output loads. 

  


===========Full_Netlist_For_Copy_Paste======================= 


SEPIC_Converter

*            _  _  _

*    ___    / \/ \/ \ V1   V1D  D1  ___      RL1

*   |VIN|___| () () |___||____|\|__|OUT|___/\  /\  /\__

*   |___|  |   L1     | || |  |/|  |___| |   \/  \/   _|_

*         _|_         | C1 |  _  _  _    |    COUT    ///

*    CIN  ___   S1 /  |    | / \/ \/ \   |__||__

*          |______/  _|    |_| () () |_     || _|_

*             _|_               L1B   _|_      ///

*             ///                     ///

VP        VP     0      DC     3.141592653589793

VT        VT     0      PWL    ( 0 0 1m .1m )

VD        VD     0      PWL    ( 0 0 1m  1 ) 

VIN       VIN    0      DC     5

B1        TRI    0      V =    acos( cos(v(VP)*v(VT)*2*1e6) )/v(VP) 

B2        VSW    0      V =    2*u( -v(TRI) +v(VD)) -1

B3        V1B    0      V =    5*u( v(VSW) ) 

*SXXXXXX  N+     N-     NC+    NC-    MODEL        <ON><OFF>

CIN       VIN    0      3u




RL1       VIN    V1L    1


L1        V1L    V1     100u

S1        V1     0      VSW    0      SWP

C1        V1     V1D    3u

L1D       V1D    V1DL   100u

RL1D      V1DL   0      1

D1        V1D    OUT5K  DD

R1        OUT5K  0      5k

COUT1     OUT5K  0      3u


RL2       VIN    V2L    1

L2        V2L    V2     100u

S2        V2     0      VSW    0      SWP

C2        V2     V2D    3u

L2D       V2D    V2DL   100u

RL2D      V2DL   0      1

D2        V2D    OUT50  DD

R2        OUT50  0      50

COUT2     OUT50  0      3u


RL3       VIN    V3L    1

L3        V3L    V3     100u

S3        V3     0      VSW    0      SWP

C3        V3     V3D    3u

L3D       V3D    V3DL   100u

RL3D      V3DL   0      1

D3        V3D    OUT10  DD

R3        OUT10  0      10

COUT3     OUT10  0      3u




.MODEL    SWP    SW(    VT=2.6m VH=.2  RON=1m  ROFF=100MEG)

.model    DD     D(     IS=3.15e-18 ) 


*TRAN     TSTEP  TSTOP  TSTART TMAX        ?UIC?

.tran    .01u    1m    0      .01us   

*=========Run_Sim============================================ 

.control 

run 

set       pensize = 2 

plot      out5k out50 out10 vs   v(vd)


.endc 

.end