*=============Buck_Duty_Cycle_Plots=======================


The Buck Converter is not a large circuit. So it is 

not hard to run three identical circuits having three

different loads at the same time. 



Buck_Converter

*                 _  _  _

*  ___   /  V1   / \/ \/ \   ___     R1 5K->10

* |VIN|_/  ______| () () |__|OUT|__/\  /\  /\__

* |___| S1   _|_    L1      |___|    \/  \/   _|_

*             ^     100u      |    C1         ///

* 1MHz       /_\              |__||__ 3u

*             |   Freq = 9K      || _|_ 

*            _|_  Z=5.8Ohms         ///

*            ///



=======================================================================


buckloaded.jpg


         plot      out5k out50 out10 vs vd



=======================================================================



Plotting all the outputs as a function of duty cycle

shows that a more heavily loaded buck converter is

acting more linear in relationship to the duty cycle.




===========Full_Netlist_For_Copy_Paste======================= 

Buck_Converter_Loaded

*                 _  _  _

*  ___   /  V1   / \/ \/ \   ___     R1

* |VIN|_/  ______| () () |__|OUT|__/\  /\  /\__

* |___| S1   _|_    L1      |___|    \/  \/   _|_

*             ^     100u      |    C1         ///

* 1MHz       /_\              |__||__ 3u

*             |   Freq = 9K      || _|_ 

*            _|_  Z=5.8Ohms         ///

*            ///

VP        VP     0      DC     3.141592653589793

VT        VT     0      PWL    ( 0 0 1m .1m )

VD        VD     0      PWL    ( 0 0 1m  1 ) 

B_TRI     TRI    0      V =    acos( cos(v(VP)*v(VT)*2*1e6) )/v(VP) 

B_SW      PWM    0      V =    2*u( -v(TRI) +v(VD)) -1

B_ON      VON    0      V =    5*u( v(PWM) ) 


VIN       VIN    0      DC     5

*SXXXXXX  N+     N-     NC+    NC-    MODEL        <ON><OFF>


S1        VIN    V1     PWM    0      SWP

D1        ID1    V1     DD

L1        V1L    OUT5k  100u 

C1        OUT5k  0      3u

R1        OUT5k  0      5K

RD        ID1    0      1m

RL        V1     V1L    1m


S2        VIN    V2     PWM    0      SWP

D2        ID2    V2     DD

L2        V2L    OUT50  100u 

C2        OUT50  0      3u

R2        OUT50  0      50

RD2       ID2    0      1m

RL2       V2     V2L    1m


S3        VIN    V3     PWM    0      SWP

D3        ID3    V3     DD

L3        V3L    OUT10  100u 

C3        OUT10  0      3u

R3        OUT10  0      10

RD3       ID3    0      1m

RL3       V3     V3L    1m



.MODEL    SWP    SW(    VT=2.6m VH=.2  RON=10u  ROFF=100MEG)

.model    DD     D(     IS=3.15e-18 ) 


*TRAN     TSTEP  TSTOP  TSTART TMAX        ?UIC?

.tran    .01u    1m    0      .01us   

*=========Run_Sim============================================ 

.control 

run 

set       pensize = 2 

plot      out5k out50 out10 vs vd


.endc 

.end