*=============Sweeping_Load_VoltageMultiplier=======================
Sometimes it is important to see how well something can handle
a load output current over several orders of magnitude. It is
easy to do this in a single transient analysis.
Using a piece wise linear voltage source "VL" , a voltage can almost
be ramped up several orders of magnitude. This voltage can then
be converted to a current source applied to an output node "OUT".
=======================================================================
VL VL 0 PWL ( 0 1p .5m 1n .6m 100n .7m 1u .8m 10u .9m 100u 1m 1000u )
BLOAD OUT 0 I = v(VL)
=======================================================================
Multipliers found good use for supplying the high voltages
needed for CRT TVs. So how much load can such a voltage
multiplier provide given 5nF caps are being switched at
100KHz?
=======================================================================
Voltage_Multiplier
* ___ C1 V1 C3 V3
* |VAC|_||_____________||_________
* |___| || _|_ _|_ || _|_ _|_
* D1 ^ D2\ / ^ D4 \ /
* /_\ _v_ D3/_\ _v_
* | | | | ___ 1Meg
* ________|__||__|______|__||__|______|Out|__/\ /\ /\__
* _|_ ||C2 V2 ||C4 |___| \/ \/ _|_
* /// V4 D5 ///
The switch capacitor equation is as follows.
R_eq = 1/(freq_clock*C)
= 1/(5e-9*1e+5) = 2KOhms
=======================================================================
Voltage_Multiplier
* ___ C1 V1 C3 V3
* |VAC|_||_____________||_________ _____
* |___| || _|_ _|_ || _|_ _|_ | _|_
* D1 ^ D2\ / ^ D4 \ / | / _ \
* /_\ _v_ D3/_\ _v_ | \/ \/
* | | | | _|_ /\_/\ BOUT
* ________|__||__|______|__||__|__|Out| \___/
* _|_ ||C2 V2 ||C4 |___| _|_
* /// ///
So this is where the logarithmic current load sweep comes in handy.
First wait for the charge pump to settle. Then ramp up a load current.
=======================================================================
The output voltage will drop when the load
resistance is about the same as the output impedance
of the voltage source.
One can see that the output voltage is really
dropping at 1msec.
=======================================================================
At that time, the load current is at 1mA.
A 1mA load current corresponds to a 6.6volt
drop in output voltage. That corresponds to
about an output impedance of 6.6kOhms. Which
is about three times larger than a single
5nf capacitor is when switching at 100kHz.
===========Full_Netlist_For_Copy_Paste=======================
Voltage_Multiplier
* ___ C1 V1 C3 V3
* |VAC|_||_____________||_________
* |___| || _|_ _|_ || _|_ _|_
* D1 ^ D2\ / ^ D4 \ /
* /_\ _v_ D3/_\ _v_
* | | | | ___ 1Meg
* ________|__||__|______|__||__|______|Out|__/\ /\ /\__
* _|_ ||C2 V2 ||C4 |___| \/ \/ _|_
* /// V4 D5 ///
*.OPTIONS GMIN=1p METHOD=gear ABSTOL=1u TEMP=27 srcsteps = 1 gminsteps = 1
*.OPTIONS RELTOL=.001 ABSTOL=1n VNTOL=1n ITL4=500 ITL1=400
*======== ====== ====== ====== ====== ====== ====== ====== ======
VAC VAC 0 DC 0 PULSE( -5 5 1p 1n 1n 5u 10u )
VL VL 0 PWL ( 0 1p .5m 1n .6m 100n .7m 1u .8m 10u .9m 100u 1m 1000u )
BLOAD OUT 0 I = v(VL)
D1 0 V1 DD
D2 V1 V2 DD
D3 V2 V3 DD
D4 V3 OUT DD
C1 VAC V1 5n
C2 0 V2 5n
C3 V1 V3 5n
C4 V2 OUT 5n
ROUT OUT 0 100meg
.model DD D(IS=3.15e-18 RS=10)
.control
set pensize = 2
tran 1u 1m 0 1u
plot out
plot vl ylog
plot v1
.endc
.end